Aminet 33/Aminet 33 - October 1999.iso/Aminet/util/time/SetDST.lha/SetDST-1.6/Install-SetDST

Text File | 1999-07-31 | 9.5 KB | 385 lines

;  $VER: InstallSetDST 1.3 (30.7.99) Copyright © 1999 by Stefan Falke
;  $Revision: 1.3 $ $Date: 1999/07/31 16:17:32 $

(set prog_name "SetDST")

(set destdev "DH0:")
(set destdir "SetDST")
(set Install_dest destdev)

(set @default-dest "")

(set defuser @user-level)

(set vernum (getversion))
(set os_ver (/ vernum 65536))
(set os_rev (- vernum (* os_ver 65536)))

(set ivernum @installer-version)
(set iver (/ ivernum 65536))
(set irev (- ivernum (* iver 65536)))

(set lang_en 0)
(set lang_dk 1)
(set lang_de 2)
(set lang_fr 3)
(set lang_no 4)
(set lang_builtin lang_en)

(set #lch_enu "English")
(set #lch_dku "Dansk")
(set #lch_deu "Deutsch")
(set #lch_fru "Français")
(set #lch_nou "Norsk")

(set #lch_enl "english")
(set #lch_dkl "dansk")
(set #lch_del "deutsch")
(set #lch_frl "français")
(set #lch_nol "norsk")

(set language lang_builtin)
(if (= #lch_enl @language) (set language lang_en))
(if (= #lch_dkl @language) (set language lang_dk))
(if (= #lch_del @language) (set language lang_de))
(if (= #lch_frl @language) (set language lang_fr))
(if (= #lch_nol @language) (set language lang_no))

(if (= language lang_de) (
    (set #chdir "Bitte Ziel-Verzeichnis für\nInstallation auswählen.\n\nEin eigenes Verzeichnis wird nicht\nautomatisch erzeugt.")
    (set #chdirhelp "Sie müssen jetzt den Pfad des Verzeichnisses angeben, in das die Dateien kopiert werden sollen.\nNoch nicht vorhandene Verzeichnisse können von diesem Installationprogramm aus angelegt werden und mit einem Schubladen-Icon versehen werden.")

    (set #lchelp "Wählen Sie den SetDST Sprachen-Katalog der installiert werden soll.")
    (set #askcatdir "In welchem Verzeichnis soll der Sprachen-Katalog installiert werden?")

    (set #owhelp "Wenn Sie diesen Requester mit 'Ja' beantworten, wird eine eventuell schon vorhandene %sVersion komplett überschrieben!")
    (set #owhelp2 "Wenn Sie diesen Requester mit 'Ja' beantworten, wird eine eventuell schon vorhandene Datei komplett überschrieben!")

    (set #askinstall1 "Wollen sie das Hauptprogramm erneut installieren?")
    (set #askinstall2 "Wollen sie das Hauptprogramm mit der Version %ld.%ld installieren?")
    (set #installed1 (cat "Die Version %ld.%ld des Programmes \"%s\" ist vermutlich schon komplett in dem angegebenen Zielverzeichnis installiert.\n" #askinstall1))
    (set #installed2 (cat "ACHTUNG! In dem angegebenen Zielverzeichnis befindet sich bereits die Version %ld.%ld des Programmes \"%s\".\n" #askinstall2))

    (set #runstartup "Soll SetDST während des Startvorganges des Computers automatisch ausgeführt werden?")
    (set #rshelp "Wenn Sie diesen Requester mit 'Ja' beantworten, wird das Hauptprogramm in das WBStartup-Verzeichnis kopiert.")

    (set #pr_copycats "Kopieren des Sprachen-Katalogs")
    (set #pr_copydata "Kopieren der Zeitzonen-Datei")
    (set #pr_copyguide "Kopieren der Bedienungsanleitung")
    (set #pr_copytools "Kopieren der Hilfsprogramme")
    (set #pr_copymain "Kopieren des Hauptprogrammes")

    (set #newer "neuere ")
    (set #older "ältere ")
    (set #no "Nein")
    (set #yes "Ja")
)(
    (set #chdir "Please select a destination directory\nfor the installation.\n\nNo drawer will be created by default.")
    (set #chdirhelp "You have to specify now the path of the drawer in which all files shall be copied.\nNon existant drawers can be created from within this install script including their accompanying icons.")

    (set #lchelp "Please select the language catalog to be installed")
    (set #askcatdir "In which drawer do you want the catalog to be installed?")

    (set #owhelp "If you respond to this requester with 'Yes', a possibly existing %sversion will be written over completely!")
    (set #owhelp2 "If you respond to this requester with 'Yes', a possibly existing file will be written over completely!")

    (set #askinstall1 "Do you want to install the main program again?")
    (set #askinstall2 "Do you want to install the main program with version %ld.%ld?")
    (set #installed1 (cat "Version %ld.%ld of the program \"%s\" presumedly has already been installed completely.\n" #askinstall1))
    (set #installed2 (cat "ATTENTION! Version %ld.%ld of the program \"%s\" already exists in the destination drawer.\n" #askinstall2))

    (set #runstartup "Do you want SetDST to be run automatically during computer startup?")
    (set #rshelp "If you respond to this requester with 'Yes', the main program will be copied to the SBStartup drawer.")

    (set #pr_copycats "Copy language catalog")
    (set #pr_copydata "Copy timezone data file")
    (set #pr_copyguide "Copy user guide")
    (set #pr_copytools "Copy tools")
    (set #pr_copymain "Copy main program")

    (set #newer "newer ")
    (set #older "older ")
    (set #no "No")
    (set #yes "Yes")
))

(procedure startcopy
    (working)

    (set file prog_name)
    (set Install_src "")

    (if (= copywbs 1)
        (set ddir "sys:wbstartup")
        (set ddir @default-dest)
    )
    (set dfile (tackon ddir prog_name))
    (checkMain)

    (if (= docopy 1) (
        (docopyMain)

        (set sdir "C")
        (set ddir (tackon Install_dest "C"))
        (docopyTools)

        (docopyCats)

        (set dfile "SetDST.guide")
        (set file (tackon Install_src dfile))
        (docopyGuides)

        (set sdir "S")
        (if (= copywbs 1)
            (set ddir "S:")
            (set ddir (tackon Install_dest "S"))
        )
        (docopyData)

    ))

)

(procedure chooseWBStart
    (set copywbs (askbool
            (prompt    #runstartup)
            (help        #rshelp)
            (choices #yes #no)
        )
    )
)

(procedure chooseCats
    (set catalog (askchoice
            (choices #lch_enu #lch_dku #lch_deu #lch_fru #lch_nou)
            (prompt #lchelp)
            (help #lchelp)
            (default language)
        )
    )

    (if (= catalog lang_en) (set #ulcat #lch_enl))
    (if (= catalog lang_dk) (set #ulcat #lch_dkl))
    (if (= catalog lang_de) (set #ulcat #lch_del))
    (if (= catalog lang_fr) (set #ulcat #lch_frl))
    (if (= catalog lang_no) (set #ulcat #lch_nol))

    (if (= catalog lang_builtin) (set #ulcat ""))
    (if (<> #ulcat "") (
        (if (= copywbs 1)(
            (set catdirc 1)
        )(
            (set catdirc (askchoice
                    (choices (tackon @default-dest (cat "Catalogs/" #ulcat)) (cat "LOCALE:Catalogs/" #ulcat) )
                    (prompt #askcatdir)
                    (help #askcatdir)
                    (default 0)
                )
            )
        ))

        (if (= catdirc 0) (
            (set catdir @default-dest)
        )(
            (set catdir "LOCALE:")
            (if (< (exists "LOCALE:" (noreq)) 2) (
                (makedir "sys:Locale")
                (makeassign "LOCALE" "sys:Locale")
            ))
            )
        )
    ))
)

(procedure docopyCats
    (if (<> #ulcat "") (
        (if (< (exists (tackon catdir "Catalogs")) 2)
            (makedir (tackon catdir "Catalogs"))
        )
        (if (< (exists (tackon catdir (cat "Catalogs/" #ulcat)) ) 2)
            (makedir (tackon catdir (cat "Catalogs/" #ulcat)) )
        )
        (copylib
            (prompt #pr_copycats)
            (help @copylib-help)
            (source (cat (tackon Install_src "Catalogs/") #ulcat "/setdst.catalog"))
            (dest (tackon catdir (cat "Catalogs/" #ulcat)) )
            (optional "nofail")
            (confirm)
        )
    ))
)

(procedure docopyData
    (if (< (exists ddir) 2)
        (makedir ddir)
    )
    (copyfiles
        (prompt #pr_copydata)
        (help @copyfiles-help)
        (source sdir)
        (dest ddir)
        (pattern "#?.dat")
        (confirm)
    )
)

(procedure docopyTools
    (if (< (exists ddir) 2)
        (makedir ddir)
    )
    (copyfiles
        (prompt #pr_copytools)
        (help @copyfiles-help)
        (source sdir)
        (dest ddir)
        (pattern "#?")
        (confirm)
    )
)

(procedure docopyGuides
    (if (= (exists file) 1)
        (copyfiles
            (prompt #pr_copyguide)
            (help @copyfiles-help)
            (source file)
            (dest Install_dest)
            (infos)
            (optional "nofail")
            (confirm)
        )
    )

    (if (>= os_ver 39)
        (tooltype
            (dest (tackon Install_dest dfile))
            (setdefaulttool "MultiView")
        )
        (tooltype
            (dest (tackon Install_dest dfile))
            (setdefaulttool "AmigaGuide")
        )
    )
)

(procedure docopyMain
    (copyfiles
        (prompt #pr_copymain)
        (help @copyfiles-help)
        (source file)
        (dest ddir)
        (infos)
        (optional "force")
        (confirm)
    )
)

(procedure checkMain
    (if (= (exists dfile) 1) (
        (set ver_source (getversion file))
        (set ver_s (/ ver_source 65536))
        (set rev_s (- ver_source (* ver_s 65536)))

        (set ver_dest (getversion dfile))
        (set ver_d (/ ver_dest 65536))
        (set rev_d (- ver_dest (* ver_d 65536)))

        (if (= ver_source ver_dest) (
            (set vprompt (#installed1 ver_s rev_s prog_name))
            (set vhelp (#owhelp ""))
            (set docopy
                (askbool
                    (prompt    vprompt)
                    (help        vhelp)
                    (choices #yes #no)
                )
            )
            (if (= @user-level 0) (set docopy 1))
        ))
        (if (< ver_source ver_dest) (
            (set vprompt (#installed2 ver_d rev_d prog_name ver_s rev_s))
            (set vhelp (#owhelp #newer))
            (set docopy
                (askbool
                    (prompt    vprompt)
                    (help        vhelp)
                    (choices #yes #no)
                )
            )
            (if (= @user-level 0) (set docopy 0))
        ))
        (if (> ver_source ver_dest) (
            (set vprompt (#installed2 ver_d rev_d prog_name ver_s rev_s))
            (set vhelp (#owhelp #older))
            (set docopy
                (askbool
                    (prompt    vprompt)
                    (help        vhelp)
                    (choices #yes #no)
                )
            )
            (if (= @user-level 0) (set docopy 1))
        ))
    )(
        (set docopy 1)
    ))
)

(procedure choosedestdir
    (if (= (exists destdev (noreq)) 0) (
        (set destdev (cat (getdevice "sys:") ":"))
        (set Install_dest destdev)
    ))
    (if (= @user-level 0)
        (set Install_dest (cat destdev destdir))
        (set Install_dest destdev)
    )
    (set @default-dest Install_dest)

    (set Install_dest
        (askdir
            (prompt    #chdir)
            (help        #chdirhelp)
            (default    @default-dest)
            (newpath)
            (disk)
        )
    )

    (if (= @default-dest Install_dest) (
        (if (= (exists @default-dest) 0) (
            (makedir @default-dest
                    (infos)
            )
        ))
    )(
        (set @default-dest Install_dest)
    ))

    (user defuser)
)

;
; Start
;

(if (= iver 0) (
    (set #langhelp "Please choose your language\nBitte Sprache auswählen")
    (set language (askchoice
            (choices #lch_enu #lch_dku #lch_deu #lch_fru #lch_nou)
            (prompt #langhelp)
            (help #langhelp)
            (default language)
        )
    )
))

(choosedestdir)
(chooseWBStart)
(chooseCats)

(startcopy)

(exit)